游戏开发系列一：游戏中的敌人(7)

这一讲，我们来结束跟踪导弹的学习。

　　五、跟踪导弹（续完）

　　上次我们已经知道怎样让导弹的旋转看起来像那么回事，紧接着就是让导弹运动起来了。

　　导弹的一些属性，我们需要好好定义一下，这是完整的初始化函数：

init = function () {
 enemy._x = 40;
 enemy._y = 350;
 enemy._rotation = 0;
 enemy_obj.MAXAngle = 6;
 enemy_obj.MAXSpeed = 4;
 enemy_obj.speedX = enemy_obj.speedY=0;
 clickable = true;
};

　　我们有了一个新的属性：enemy_obj.MAXSpeed，这个属性代表这导弹的速度，不管导弹的朝向如何，速度总是有一个值的，我们在这里设置它。在导弹运动的时候，就按照上一讲里面已经计算出来的方向和速度来前进。下面我们来看，怎样确定 x 和 y 方向的速度：

　　从上面的图片，我们可以根据三角计算得到导弹在 x 和 y 方向的速度，而速度之和正好是等于导弹的 MAXSpeed。

　　于是我们很容易的得到下面的代码：

dir = (refineAngle(enemy._rotation)>180) ? -1 : 1;
tempTan = Math.tan((90-enemy._rotation)*Math.PI/180);
enemy_obj.speedX = enemy_obj.MAXSpeed/Math.sqrt(1+Math.pow(tempTan, 2))*dir;
enemy_obj.speedY = tempTan*enemy_obj.speedX;

　　tempTan 是取得的三角函数值，具体的运算请对照图上的公式和上一讲的内容。

　　最后，我们要判断一下是否碰撞，如果碰撞的话，就重新来过。

if (player.hitTest(enemy._x, enemy._y, false)) {
 clearInterval(intervalID);
 init();
}

　　下面是完整的第一帧源代码，带颜色的应该在一行：

var clickable:Boolean;
var enemy_obj:Object = new Object();
var intervalID:Number;
//
init = function () {
 enemy._x = 40;
 enemy._y = 350;
 enemy._rotation = 0;
 enemy_obj.MAXAngle = 6;
 enemy_obj.MAXSpeed = 4;
 enemy_obj.speedX = enemy_obj.speedY=0;
 clickable = true;
};
onMouseMove = function () {
 player._x = _xmouse-10;
 player._y = _ymouse-10;
 updateAfterEvent();
};
onMouseDown = function () {
 if (clickable) {
  intervalID = setInterval(run, 10);
  clickable = false;
 }
};
getAngle = function ():Number {
 var dx:Number = player._x-enemy._x;
 var dy:Number = player._y-enemy._y;
 return ((Math.atan2(dy, dx)*180/Math.PI+450)%360);
};
refineAngle = function (angle:Number):Number {
 return ((angle+360)%360);
};
run = function () {
 var dx:Number = player._x-enemy._x;
 var dy:Number = player._y-enemy._y;
 var tempTan:Number;
 var angle:Number = getAngle();
 var tempAngle:Number = refineAngle(enemy._rotation-angle);
 var dir:Number = (refineAngle(tempAngle)>=180) ? 1 : -1;
 enemy._rotation = (Math.abs(tempAngle)>enemy_obj.MAXAngle)
 ? (enemy._rotation+enemy_obj.MAXAngle*dir) : angle;
 // Get Speed
 dir = (refineAngle(enemy._rotation)>180) ? -1 : 1;
 tempTan = Math.tan((90-enemy._rotation)*Math.PI/180);
 enemy_obj.speedX = enemy_obj.MAXSpeed/Math.sqrt(1+Math.pow(tempTan, 2))*dir;
 enemy_obj.speedY = tempTan*enemy_obj.speedX;
 // Move Enemy
 enemy._x += enemy_obj.speedX;
 enemy._y -= enemy_obj.speedY;
 if (player.hitTest(enemy._x, enemy._y, false)) {
  clearInterval(intervalID);
  init();
 }
};
// Run Program
init();

　　这次的源代码请在这里下载。本系列的讨论在这里，当然也可以在这里直接提问。

　　下一讲，开始新的内容。

（待续）

编辑：eastecho